as 控制帧频
示例:假设swf文件的帧率为30,场景中有影片实例"wiyi_mc"。要改变"wiyi_mc"的帧率，则:
ASFps.initialize(wiyi_mc);//为wiyi_mc附加帧率属性
wiyi_mc._fps=10; //将wiyi_mc的帧率设置为10,此后wiyi_mc._fps将以10帧每秒的帧率播放/* ASFps类是一个可以在运行时模拟改变影片的帧率的包装类。
示例:假设swf文件的帧率为30,场景中有影片实例"wiyi_mc"。要改变"wiyi_mc"的帧率，则:
ASFps.initialize(wiyi_mc);//为wiyi_mc附加帧率属性
wiyi_mc._fps=10; //将wiyi_mc的帧率设置为10,此后wiyi_mc._fps将以10帧每秒的帧率播放
wiyi_mc._fps="default"; //将wiyi_mc的帧率恢复为默认的30帧每秒。
wiyi_mc._fps=-20; //将wiyi_mc的帧率设置为-20,此后wiyi_mc._fps将以20帧每秒的帧率倒序播放
wiyi_mc._fps=0; //将wiyi_mc的帧率恢复为默认的30帧每秒的又一种方法。
程序中用到了"setInterval"方法，因为它会受到swf文件帧率影响，所以用ASFps类改变影片的帧率并不是
无限度的。在无法取得理想效果时，建议先阅读Flash 2004里关于"setInterval"方法的说明。
----------------------版权声明-----------------------
本程序由 wiyiflash 于2004年7月2日编写,欢迎大家访问:http://www.wiyiflash.com/bbs论坛。
向大愚、叶子表示感谢，正是受到您的启发我才开始写这段程序。
在保留此声明的前提下您可以自由地使用、复制、传播和修改本程序,谢谢。
*/
class ASFps {
private var __fps;
public var _fps;
var __fpsIntervalID:Number;
static function next(mc:MovieClip, direction:Number) {
var d = (direction>0 ? Math.ceil(direction) : Math.floor(direction));
var c = (mc._currentframe+d)%mc._totalframes;
(c == 0 ? c=mc._totalframes : null);
mc.gotoAndStop(c);
trace(c);
updateAfterEvent();
}
function setFps(fps) {
if (fps == "default" || fps == 0) {
this.__fps = fps;
clearInterval(this.__fpsIntervalID);
} else if (typeof (fps) == "number") {
//
if (this.__fps == fps) {
return;
}
trace("ID:"+this.__fpsIntervalID);
this.__fps = fps;
var direction = (fps>0 ? 1 : -1);
var f = Math.abs(fps);
if (this.__fpsIntervalID != undefined) {
clearInterval(this.__fpsIntervalID);
}
this.__fpsIntervalID = setInterval(ASFps.next, 1000/f, this, direction);
}
}
function getFps() {
return this.__fps;
}
private function ASFps() {
}
static function initialize(mc:MovieClip) {
if (mc.setFps == undefined) {
mc.__fps = 0;
mc.__fpsIntervalID = undefined;
mc.getFps = ASFps.prototype.getFps;
mc.setFps = ASFps.prototype.setFps;
mc.addProperty("_fps", mc.getFps, mc.setFps);
_global.ASSetPropFlags(mc, "setFps,getFps", 7, 1);
_global.ASSetPropFlags(mc, "__fps,__fpsIntervalID", 1, 1);
}
}
}
from:asp学习网/title:as 控制帧频/ time:2007-3-17 20:58:57
本文主题控制帧频
